home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d3
/
amac36.arc
/
BOOK15.QM
< prev
next >
Wrap
Text File
|
1991-03-16
|
10KB
|
229 lines
* (BookMarker) BOOK15.QM, v1.5b
* ┌────────────────────────[ Index of Macros ]─────────────────────────────────┐
* │(Alt_1)- Finds first word on cursor line "marked" in the document below │
* │(Alt_2)- Finds first word on cursor line in document below, "marked" or │
* │ "unmarked", and places () around selected found word in document │
* │(Alt_3)- Puts word @ cursor in Index with () around word and word in Index │
* │(F4) - Continues until the desired word & location are found using Alt_2 │
* │ │
* │(Description) - BookMarker Macros │
* │(Using) Macros - Start up and Macro Execution │
* │(Macros) - BookMarker Macros │
* │(Other) Macros - not included │
* │(Version) history │
* └────────[ be sure to leave at least one blank line at end of Index ]────────┘
* (Description):
*
* BookMarker BOOK15.QM is a series of four macros to place ()
* around selected words in QEdit documents as bookmarks. A bookmark
* can then be quickly located from an index of book-marked words
* (also prepared with these macros) at the top of the document by
* pressing Alt_1.
*
* Of the many macros I use regularly, Alt_1 is probably the one
* I use most. It has become so important I could not maneuver
* without it. Documents I use regularly are Indexed with either
* Alt_2 or 3. I can quickly get to where I want to be in a
* document or a help file by entering Alt & 1 at the same time,
* placing the cursor on the line in an Index I want to locate in
* the document, and then pressing Enter. Presto, I'm there
* without having to scroll through the document.
*
* To BEGIN, just type "START BOOK" <Enter>. All pertinent files will be
* loaded in the "Ring" for viewing, and BOOK15.MAC is read.
* Alternatively, type "START BOOK 0" <Enter> and the disk copies of all
* files in the "Ring" will be loaded ready for editing, saving time.
* (Using) Macros:
*
* To execute these macros, be sure Insert is ON and then:
* 1. Place BOOK15.MAC and BOOK15.QM in the current directory.
* 2. Load BOOK15.QM into a QEdit window.
* 3. Read the macfile BOOK15.MAC as follows:
* Esc
* M
* R
* BOOK15.MAC
* Enter
* 4. Press ALT and 1 at the same time and proceed as
* described below.
*
* These macros may also be placed in your QCONFIG.DAT file to be
* continually available.
*
* These macros require "QEdit and QMAC v2.1, February, 1990" or later.
* (Macros):
*
*┌───────────────────────────────────────────────────────────────────┐
*│(Alt_1) Finds first word on cursor line marked in document below │
*└───────────────────────────────────────────────────────────────────┘
*
* Alt_1 macro has 2 steps:
*
* 1. Press Alt and 1 at the same time. Line 1 is marked to
* highlight. Cursor down to desired line in Index.
*
* 2. Press Enter. The macro then finds the first word on the
* cursor line in the document below marked with (...).
*
*
@1 macrobegin
unmarkblock * unmark any marked blocks
begfile * go to file begin
markline * and highlight line 1
markline *
pause * pause for Index selection
wordright markword * mark first word on line
copy * copy word to scrap
endpara * go to end of Index
makectrofscreen * cursor line center of window
find "(" paste ")"
return "I" return * find first marked word in doc
jfalse NOMARK:
begline * if mark found go to begline
jump END:
NOMARK:
begfile * if no mark found go to begfile
END:
*
* 32 bytes Tue 09-11-1990 11:19:51
* This macro is 32 bytes. You may want to load this shorter version (21
* bytes) where searching starts from cursor line in Index down, not at
* the end of the Index, as above:
* @1 macrobegin
* unmarkblock * unmark any marked blocks
* begfile * go to file begin endline
* markline * highlight to show 'on'
* markline *
* pause * pause for Index selection
* wordright markword * mark first word on line
* copy * copy word to scrap
* find "(" paste ")" return * find first marked word in doc
* return
* begline * if mark found go to begline
*
* 21 bytes Tue 09-11-1990 11:22:45 added markline
*┌─────────────────────────────────────────────────────────────────────────────┐
*│(Alt_2) Finds word in document, adds () to found word and returns to Index │
*└─────────────────────────────────────────────────────────────────────────────┘
*
* Alt_2 macro has 3 steps:
*
* 1. Press Alt and 2 at the same time. The macro finds first word
* on the cursor line in the document below. If first found word
* is not the desired occurrence, press F4 for next word or until
* the desired occurrence is found.
*
* 2. When the desired word and location are found, press Enter.
* The macro places () around desired found word and then return
* to the original word in the Index.
*
* 3. Press Enter again and the macro places () around the original
* word in the Index. The cursor ends at end of the marked word in
* the Index so comments may be added. Be careful not to mark the
* same word more than once or only the first occurrence of the word
* in the document will be found with Alt_1.
*
@2 macrobegin *
wordright markword * mark first word on line
copy * copy word to scrap
find paste return return * find first word in doc
pause * pause for Enter or F4
"(" * place ( in front of word
markword * markword
gotoblockend ")" * place ) at end of word
pause * pause for Enter if OK
begfile * go to file begin
find paste return return * find selected word doc
pause * pause for Enter if OK
markword * markword
gotoblockbeg "(" * place ( in front of word
gotoblockend ") " * place ) at end of word
unmarkblock * unmark word
*
* 35 bytes Sat 07-28-1990 15:17:55
*┌─────────────────────────────────────────────────────────────────────────────┐
*│(Alt_3), Puts word @ cursor in Index with () around marked word and in Index │
*└─────────────────────────────────────────────────────────────────────────────┘
*
* Alt_3 macro has 2 steps:
*
* 1. Press Alt and 3 at the same time. Macro marks the word at the
* cursor in the document, then returns to the the end of the Index.
* The marked word in the document is then copied at the end of the
* Index with () around it. The cursor is at end of word so
* comments may be added in the Index.
*
* 2. Press Enter and the cursor returns to the beginning of
* the line of the marked word in the document.
*
@3 macrobegin *
markword * mark word at cursor
gotoblockbeg "(" * place () around word
gotoblockend ")" *
copy * copy word and ) to scrap
begfile * go to file begin
endpara return * go to end of Index
paste * paste word and )
begline "* (" endline " " * insert "* (" in front of word
unmarkblock makebotofscreen * unmark word and ()
pause * pause for comments and if OK
begline wordright markword * mark word
copy * copy word to scrap
find "(" paste ")" return * return to word in doc
return
begline * go to line begin
*
* 42 bytes Sat 07-28-1990 15:18:04
*┌────────────────────────────────────────────────────────────┐
*│(f4) Continues until desired word is found using Alt_2 │
*└────────────────────────────────────────────────────────────┘
*
* (see Alt_2 for use)
*
f4 repeatfind * repeat find until desired word
* & location are found
* 5 bytes Sat 07-28-1990 15:18:17
* (Other) Macros: See ALLMACRO.INF
*
* (Version) History:
*
* 1.0 - initial
* 1.1 - changed document
* 1.2 - modified Alt_1 to keep normal cursor line color before selecting
* an indexed word. Macro now does not find marked words in Index.
* 1.3 - changed document BOOK13.QM
* 1.3a- Changed other file names in series, this is an update.
* 1.4 - Changed down arrow #25 to ! in @1.
* - Changed .LST and .QL
* 1.5 - Modified @1 to highlight line 1 rather than ! at end
* 1.5a- Modified this file.
* 1.5b- Modified this file and added START.BAT.
* (QEdit) is not a marked Index word
* (unmarked) is not a marked Index word
* (be) is not a marked Index word
* (window) is not a marked Index word
*
*...Tom Hogshead Wed 10-31-1990